[ 456 ]

casino mrc

[StingeR] — Sun, 03 May 2015 21:32:47 GMT

С чего всё началось:
Посмотрев на работу убогого скрипта бандит ткл решил переписать его на мирц с гораздо большим функционалом!

Суть игры:
Игрок крутит барабаны. Если выпадает любая выигрышная комбинация, ему на баланс падают монетки. Пока игрок не накопит 100 монет, игра будет для него бесплатной. После 5 монет за прокрут. Эти монеты забирает себе бот.

Выигрышные комбинации:
111 - 500 монет
222 - 222 монет
228 - Минус 228 монет
333 - 1000 монет
444 - 500 монет
555 - 1000 монет
666 - Минус 666 монет
777 - 1000 монет
888 - Минус 100 монет
999 - 1000 монет
123,234,345,567,678,789 - 500 монет
456 - 4560 монет (самый большой выигрыш)
XYX - Зеркальное число +50 монет
XXY, YXX - два совпадения +20 монет + шанс 50% на смену Y соответственно шанс 10% поймать XXX :nlo:

Bonus Game:
Также каждую игру есть шанс сыграть второй раз сразу же на хаяву (Bonus GAME) Шанс выиграть в процентном соотношении всегда разный:
Шанс получить BG 10-25% всем + 1-25% тем у кого есть ТАЛИСМАН (Проценты суммируются) и того в самом удачном раскладе выбить BG составляет 50%

Грабежи:

Каждый игрок у которого есть более 500 монет, может грабить игроков у кого тоже больше 500 монет. В том числе можно грабить самого бота.
При грабеже людей, у них может быть БРОНЯ, она даёт плюсом от 3 до 20% на защиту. Статический процент защиты всего 32%
Тоесть общий процент защиты составляет не более 52% (Шанс грабануть 48% в самом худшем варианте)
Сумма грабежа случайная. От 100 до 300 монет.
Сумма морального вреда в случае провала от 50 до 250 монет.
Сумма которая ложится в банк ровна той же сумме грабежа, который бы мог был быть.

Банк:
Также можно грабануть банк. С 1 раза это нереально)) , а далее +1% за каждую попытку.
Тоесть 2 раз шанс грабануть составляет 2% и каждый последующий раз +1 процент!
Банк складывается только от неудачных грабежей.

Прокруты:
Есть прокруты личные (копятся каждым человеком) и общие
За каждый 10 прокрут бот даст 15-25 монет
За каждый 100 прокрут бот даст 500 монет
За каждый 1000 прокрут бот даст 1000 монет

Идеи для скриптов

[StingeR] — Mon, 27 Aug 2012 08:19:23 GMT

Форум: mIRC скриптинг
Описание темы: Пишите ваши мысли
Автор темы: [StingeR]
Автор последнего сообщения: Epic
Количество ответов: 25

seen

DmitRexInfo — Tue, 26 Apr 2011 18:23:24 GMT

!seen. думаю многие оценят.. а если это удалось, то увидят превосходство над еггдроп

говорить о достоинствах скрипта, все-равно что описывать принцип его работы, проговаривать каждую команду.. поэтому без этого. разве что хочется заметить - построено на хэш таблицах, и гибкость при поиске ника, а все остальное вы должны увидеть сами

!seen

примеры запросов:
!seen *ing* - найдет все ники, в которых есть слово по маске *ing*
!seen *!*@*.is74.loc - покажет пользователей с соответствующей маской по хосту
!seen DmitRex - если я в IRC, покажет мои каналы, иначе покажет мое последнее действие, а если моих ников больше 1 или бот видет меня увидет - покажет мои каналы

спасибо господам с #mirc-scripts за тесты)..c irc.senet.ru

это первая бета-версия скрипта, выложена только чтобы все ее протестировали и сообщили о багах..

в следующей версии они будут исправлены и добавлена функция, когда ищется ник, чтобы потом при заходе этого ника на канал с ботом ему сообщалось что его искали.. базы я эти создал в скрипте, а вот сделать из головы вылетело но сделаю в следующей версии обязательно)

p.s. очень надеюсь что скрипт заработает "из коробки" =)

Помощь по скриптингу

[StingeR] — Fri, 25 Mar 2011 11:03:58 GMT

Форум: mIRC скриптинг
Автор темы: [StingeR]
Автор последнего сообщения: [StingeR]
Количество ответов: 55

Библиотеки Алиасов

[StingeR] — Wed, 09 Mar 2011 15:20:34 GMT

Тема взята с http://forum.bestirc.ru/index.php?showtopic=287 , за что им большое спасибо

Как говориться зачем изобретать каждый раз велосипед?

$rduration(N) Возвращает секунды в русском формате сек./мин./день....

Code

alias rduration { return $replace($duration($1),secs,сек.,sec,сек.,mins,мин.,min,мин.,hrs,час.,hr,час.,day,день,days,дней,wk,неделя,wks,недель) }

Пример: $rduration(6000) вернет 1час. 49мин.

---
$rdata(d/m) Вернет месяц или день недели в русском формате:

Code

alias rdata {
if ($1 == m) return $replace($date(mmmm),January,Января,December,Декабря,November,Ноября,October,Октября,February,Февраля,March,Марта,April,Апреля,May,Мая,June, Июня,July,Июля,August,Августа,September,Сентября)
if ($1 == d) return $replace($date(dddd),Sunday,Воскресенье,Monday,Понедельник,Tuesday,Вторник,Wednesday,Среда,Thursday,Четверг,Friday,Пятница,Saturday,Суббота)
}

Пример: $rdata(d) $date(dd) $rdata(m) вернет Субота 29 Августа

---
$rstr(string,N) Бегущая строка для динамических приложений

Code

alias rstr { return $mid($1,$2,$calc($len($1) - $2 + 1)) $mid($1,1,$calc($2 - 1)) }

Пример: $rstr(test sword,2) вернет est sword t
--
$convert.size(N) Вернет байты в байты/килобайты/мегабайты/гигобайты

Code

alias convert.size {
   if ($1 == 0) { return --- }
   elseif ($1 < 1024) { return $1 $+ б }
   elseif ($1 > 1024)  && ($1 < 1048576) { return $round($calc($1 / 1024),2) $+ Кб }
   elseif ($1 > 1048576) && ($1 < 1073741824) { return $round($calc($1 / 1048576),2) $+ Мб }
   else { return $round($calc($1 / 1073741824),2) $+ Гб }
}

Пример: $convert.size(2845563) вернет 2.71Мб

---

$find.ip.chan(N) Ищет на текущем канале указанный IP адрес и возвращает найденные ник/и. В противном случае вернет $false

Code

alias find.ip.chan {
   var %i 1,%ip *!*@ $+  $1 | /who #
   while (%i <= $nick(#,0)) {  if ($address($nick(#,%i),2) == %ip) {  var %fnick = %fnick $nick(#,%i)  } | inc %i 1  }
   if (%fnick) {  return %fnick $+  ( $+ $1 $+ ) }
   else {  return $false  }
}

Пример: $find.ip.chan(10.10.10.10) вернет ник с текущим адресом или $false, если такого адреса нет на канале.
---
$leap.year(year) Определения високосного года.

Code

alias leap.year { if ($calc($abs($calc($1 - 2000)) % 4) == 0) { return $true } | return $false }

Пример: $leap.year(2008) вернет $true
---
$translit(string) Автоперевод строки при неправильной раскладке.

Code

translit {
if (f isin $1- || j isin $1- || t isin $1- || z isin $1- || e isin $1- || b isin $1- ) { return $replace($1-,q,й,w,ц,e,у,r,к,t,е,y,н,u,г,i,ш,o,щ,p,з,[,х,],ъ,a,ф,s,ы,d,в,f,а,g,п,h,р,j,о,k,л,l,д,;,ж,$chr(39),э,z,я,x,ч,c,с,v,м,b,и,n,т,m,ь,$chr(44),б,.,ю, ,ё,/,.,&,?) }
else { return $replace($1-,й,q,ц,w,у,e,к,r,е,t,н,y,г,u,ш,i,щ,o,з,p,х,[,ъ,],ф,a,ы,s,в,d,а,f,п,g,р,h,о,j,л,k,д,l,ж,;,э,$chr(39),я,z,ч,x,с,c,м,v,и,b,т,n,ь,m,б,$chr(44),ю,.,ё, ,.,/) }
}

Пример: $translit(ghjdthrf) вернет проверка
Примечание: Чувствительный к регистру
---
$massive(name,N/-ipo[N],value,...value) Примитивные массивы и работа с ним. (возможно упрощенная(?) работа с токенами.)
Примечание: массив создаёся переменной и выглядит как %value,value....value.
Свойства:
.num число элементов в массиве.
.add Добавить элемент в массив
-i - перезаписать N элемент массива
.rem Удалить элемент из массива
-i -удалить N элемент массива.
-o -Все значения равные value
и т.п. (лень писать)
Взможности: поиск, перезапись,возвращения элемента.

.find
.repl.
.wild

Code

massive {
   if ($1 == $null) { halt }
   if  ($prop == num) { return $numtok(% [ $+ [ $1 ]  ],44) }
   elseif ($2 == $null) { halt }
   elseif ($prop == add) {
     if ($3 == -i) && ($4 isnum) {   set % [ $+ [ $1 ]  ]  $instok(% [ $+ [ $1 ]  ],$2,$4,44)  }
     else { set % [ $+ [ $1 ]  ]   $iif(% [ $+ [ $1 ] ],% [ $+ [ $1 ] ] $+ $chr(44),% [ $+ [ $1 ] ])  $+ $2  }
   }
   elseif ($prop == rem) {
     if ($2 == -i) && ($3 isnum) && ($3 <= $numtok( % [ $+ [ $1 ]  ],44)) { set % [ $+ [ $1 ]  ] $deltok(% [ $+ [ $1 ]  ],$3,44) }
     elseif ($2 == -o) {
       if ($matchtok(% [ $+ [ $1 ]  ],$3,0,44) >= 2) {  while ($matchtok(% [ $+ [ $1 ]  ],$3,0,44)) {   set % [ $+ [ $1 ]  ] $remtok(% [ $+ [ $1 ]  ],$3,44) } }
       else { set % [ $+ [ $1 ]  ] $remtok(% [ $+ [ $1 ]  ],$3,44) }
     }
     elseif ($left($2,2) == -p) && ($remove($2,-p) isnum) { set % [ $+ [ $1 ]  ] $remtok(% [ $+ [ $1 ]  ],$3,$remove($2,-p),44)  }
   }
   elseif ($prop == find) {
     if ($left($2,1) == -p) && ($remove($2,p) isnum) { return $findtok(% [ $+ [ $1 ]  ],$3,$remove($2,-p),44) }
     elseif ($2 == -o) { return $findtok(% [ $+ [ $1 ]  ],$3,0,44) }
     else { return $findtok(% [ $+ [ $1 ]  ],$2,1,44) }
   }
   elseif ($prop == repl) {
     if ($2 == -p) && ($3 isnum) { set % [ $+ [ $1 ]  ] $puttok(% [ $+ [ $1 ]  ],$4,$3,44) }
     elseif ($2 == -o) { if ($matchtok(% [ $+ [ $1 ]  ],$3,0,44) >= 2) {  var %i 1 | while ($matchtok(% [ $+ [ $1 ]  ],$3,0,44)) {   set % [ $+ [ $1 ]  ] $reptok(% [ $+ [ $1 ]  ],$3,$4,1,44) | inc %i 1  } }   }
     else {  set % [ $+ [ $1 ]  ] $reptok(% [ $+ [ $1 ]  ],$2,$3,1,44) }
   }
   elseif ($prop == wild) {
     if ($2 == -l)  { var %i 4 | while ($0 >= %i) {  if ($3 == $gettok(% [ $+ [ $1 ]  ],$ [ $+ [ %i ] ],44)) {  inc %i 1 } | else {  return $false | halt }   } | return $true }
     else { var %i 3 | while ($0 >= %i) {  if ($gettok(% [ $+ [ $1 ]  ],$2,44) == $gettok(% [ $+ [ $1 ]  ],$ [ $+ [ %i ] ],44)) {  inc %i 1 } | else {  return $false | halt }   } | return $true }
   }
   else {
     if ($2 == -i) { return $findtok(% [ $+ [ $1 ]  ],$3,1,44) }
     else { return  $gettok(% [ $+ [ $1 ]  ],$2,44) }
   }
}

$parse(string) Вернет строку с подкрашеными красным латинскими буквами(удобно, когда русские буквы подменяют латинскими)

Code

parse {
   var %i = 1, %j = $1-, %x
   while (%i <= $len(%j)) {
     if $asc($mid(%j,%i,1)) < 192 { %x = %x $+ 4 $+ $mid(%j,%i,1) $+ }
     else { %x = %x $+ $mid(%j,%i,1) }
     inc %i
   }
   return %x
}

Пример: $parse(тecт стpoки) вернет тecт стpoки

--
$urlencode(string) Вернет строку, закодированую аля url

Code

urlencode {
   var %i = 0, %r
   while (%i < $len($1-)) {
     inc %i
     %r = %r $+ $chr(37) $+ $base($asc($mid($1-,%i,1)),10,16,2)
   }
   return %r
}

Пример: $urlencode(здесь был я) вернет %E7%E4%E5%F1%FC%20%E1%FB%EB%20%FF

--
$nicks(channel) Вернет все ники канала channel (p.s. вы должны быть на этом канале)

Code

nicks {
   var %i = 1, %nicks, %chan = $1
   while (%i <= $nick(%chan,0)) {
     %nicks = %nicks $nick(%chan,%i)
     inc %i
   }
   return %nicks
}

Пример: $nicks(#bestirc) вернет ServBot IRCBot yXo Иста`aw _derox`off... и т.д.

Скрипты на вашу мирку через каторую вы сидите

[StingeR] — Sun, 10 Oct 2010 04:39:49 GMT

Скрипт Потщета слов и символов произнесёных вами(в нарко бай стингер это уже есть)

on 1:input:*: { if ($left($1-,1) != /) { set %simvoli $calc(%simvoli + $len($1-)) | set %slova $calc(%slova + $0) } }

Создастся 2 переменные %simvoli и %slova
Штобы сказать в канал эти данные добавляем в менюшки к примеру "Я сказал %slova слов и напечатал %simvoli символов"

Автоидентификация ника

[StingeR] — Sun, 10 Oct 2010 04:37:18 GMT

Форум: mIRC скриптинг
Автор темы: [StingeR]
Автор последнего сообщения: _Dimon_
Количество ответов: 2

Karma

DmitRexInfo — Tue, 21 Sep 2010 13:18:32 GMT

Code

on *:START: { hmake karma 1 | $iif($exists(channels\karma.txt),hload karma channels\karma.txt) }
on *:JOIN:*: {
   if $nick == $me { hadd karma join. $+ $nick $ctime | hadd karma online. $+ $nick 0 }
}
on *:TEXT:*:*: {
     $iif(!$hget(karma,join. $+ $nick),hadd karma join. $+ $nick $ctime) | hadd karma online. $+ $nick $calc($ctime - $hget(karma,join. $+ $nick)) | var %t = спасибо 10х 10x спс спасиб cgc thanks фэнкс фенкс cgfcb,j
     if $nick !isin $gettok($1-,1-2,32) && $me !isin $gettok($1-,1-2,32) {
       if $hget(karma,set. $+ $nick) {
         if +1 isin $gettok($1-,1-2,32) || -1 isin $gettok($1-,1-2,32) { msg $chan $nick $+ , Вы сможете управлять кармой через $duration($hget(karma,set. $+ $nick)) }
       }
       else {
         if ($1 == +1 && $strip($2) ison $chan) || ($2 == +1 && $remove($strip($1),$chr(44),$chr(94),$chr(58)) ison $chan) {
           $iif(!$hget(karma,karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),hadd karma karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58))) 0 0 0 0 0 0)
           hadd karma karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58))) $calc(($gettok($hget(karma,karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),1,32) + 1) + $hget(karma,online. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))) / 86400) $iif($gettok($hget(karma,karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),2,32),$ifmatch,1) $iif($gettok($hget(karma,karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),3,32),$ifmatch,0) $iif($gettok($hget(karma,karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),4,32),$ifmatch,0) $iif($gettok($hget(karma,karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),5,32),$ifmatch,0) $iif($gettok($hget(karma,karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),6,32),$ifmatch,0)
           hadd karma karma. $+ $nick $gettok($hget(karma,karma. $+ $nick),1,32) $iif($gettok($hget(karma,karma. $+ $nick),2,32),$calc($ifmatch + 1),1) $gettok($hget(karma,karma. $+ $nick),3,32) $gettok($hget(karma,karma. $+ $nick),4,32) $gettok($hget(karma,karma. $+ $nick),5,32) $gettok($hget(karma,karma. $+ $nick),6,32)
           hadd -zu3600 karma set. $+ $nick 3600
         }
         elseif ($1 == -1 && $strip($2) ison $chan) || ($2 == -1 && $remove($strip($1),$chr(44),$chr(94),$chr(58)) ison $chan) {
           $iif(!$hget(karma,karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),hadd karma karma. $+ $iif($1 == +1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58))) 0 0 0 0 0 0)
           hadd karma karma. $+ $iif($1 == -1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58))) $gettok($hget(karma,karma. $+ $iif($1 == -1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),1,32) $iif($gettok($hget(karma,karma. $+ $iif($1 == -1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),2,32),$ifmatch,1) $iif($gettok($hget(karma,karma. $+ $iif($1 == -1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),3,32),$ifmatch,0) $iif($gettok($hget(karma,karma. $+ $iif($1 == -1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),4,32),$ifmatch,0) $calc($iif($gettok($hget(karma,karma. $+ $iif($1 == -1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),5,32),$ifmatch,0) + 1) $iif($gettok($hget(karma,karma. $+ $iif($1 == -1,$2,$remove($strip($1),$chr(44),$chr(94),$chr(58)))),6,32),$ifmatch,0)
           hadd karma karma. $+ $nick $gettok($hget(karma,karma. $+ $nick),1,32) $iif($gettok($hget(karma,karma. $+ $nick),2,32),$ifmatch,1) $gettok($hget(karma,karma. $+ $nick),3,32) $gettok($hget(karma,karma. $+ $nick),4,32) $gettok($hget(karma,karma. $+ $nick),5,32) $calc($gettok($hget(karma,karma. $+ $nick),6,32) - 1)
           hadd -zu3600 karma set. $+ $nick 3600
         }
       }
       if $istok(%t,$remove($2,$chr(44),$chr(46)),32) && $remove($strip($1),$chr(44),$chr(94),$chr(58)) ison $chan {
         $iif(!$hget(karma,karma. $+ $remove($strip($1),$chr(44),$chr(94),$chr(58))),hadd karma karma. $+ $remove($strip($1),$chr(44),$chr(94),$chr(58)) 0 0 0 0 0 0)
         hadd karma karma. $+ $remove($strip($1),$chr(44),$chr(94),$chr(58)) $gettok($hget(karma,karma. $+ $remove($strip($1),$chr(44),$chr(94),$chr(58))),1,32) $iif($gettok($hget(karma,karma. $+ $remove($strip($1),$chr(44),$chr(94),$chr(58))),2,32),$ifmatch,1) $calc($gettok($hget(karma,karma. $+ $remove($strip($1),$chr(44),$chr(94),$chr(58))),3,32) + 1) $gettok($hget(karma,karma. $+ $remove($strip($1),$chr(44),$chr(94),$chr(58))),4,32) $gettok($hget(karma,karma. $+ $remove($strip($1),$chr(44),$chr(94),$chr(58))),5,32) $gettok($hget(karma,karma. $+ $remove($strip($1),$chr(44),$chr(94),$chr(58))),6,32)
         hadd karma karma. $+ $nick $gettok($hget(karma,karma. $+ $nick),1,32) $iif($gettok($hget(karma,karma. $+ $nick),2,32),$ifmatch,1) $gettok($hget(karma,karma. $+ $nick),3,32) $calc($gettok($hget(karma,karma. $+ $nick),4,32) + 1) $iif($gettok($hget(karma,karma. $+ $nick),5,32),$ifmatch,0) $iif($gettok($hget(karma,karma. $+ $nick),6,32),$ifmatch,0)
       }
     }
     if $1 == !karma || $1 == !карма {
       $iif(!$hget(karma,join. $+ $iif($2 && $2 ison $chan,$2,$nick)),hadd karma join. $+ $iif($2 && $2 ison $chan,$2,$nick) $ctime) | hadd karma online. $+ $iif($2 && $2 ison $chan,$2,$nick) $calc($ctime - $hget(karma,join. $+ $iif($2 && $2 ison $chan,$2,$nick)))
       if $2 && $hget(karma,karma. $+ $2) && $2 != $nick { msg $chan $nick $+ , Карма у $2 $calc($remove($gettok($hget(karma,karma. $+ $2),1,32),$chr(43)) - $remove($gettok($hget(karma,karma. $+ $2),5,32),$chr(45))) $chr(91) $+ + $+ $iif($gettok($hget(karma,karma. $+ $2),1,32),$ifmatch,0) $+ / $+ $iif($gettok($hget(karma,karma. $+ $2),5,32),$ifmatch,0) $+ $chr(93) $chr(40) $+ повышал: $iif($gettok($hget(karma,karma. $+ $2),6,32),$ifmatch,0) $+ ; занижал: $iif($gettok($hget(karma,karma. $+ $2),5,32),$ifmatch,0) $+ $chr(41) его поблагодарили: $iif($gettok($hget(karma,karma. $+ $2),3,32),$ifmatch,0) он поблагодарил: $iif($gettok($hget(karma,karma. $+ $2),4,32),$ifmatch,0) $+ . В online: $duration($hget(karma,online. $+ $2)) $+ , + $+ $calc($hget(karma,online. $+ $2) / 86400) к его карме }
       else { msg $chan $nick $+ , $iif($2 && !$hget(karma. $+ $2),Кармы у $2 нет $+ $chr(44) в,В) $+ аша карма $calc($remove($gettok($hget(karma,karma. $+ $nick),1,32),$chr(43)) - $remove($gettok($hget(karma,karma. $+ $nick),5,32),$chr(45))) $chr(91) $+ + $+ $iif($gettok($hget(karma,karma. $+ $nick),1,32),$ifmatch,0) $+ / $+ $iif($gettok($hget(karma,karma. $+ $nick),5,32),$ifmatch,0) $+ $chr(93) $chr(40) $+ повышали: $iif($gettok($hget(karma,karma. $+ $nick),6,32),$ifmatch,0) $+ ; занижали: $iif($gettok($hget(karma,karma. $+ $nick),5,32),$ifmatch,0) $+ $chr(41) вас поблагодарили: $iif($gettok($hget(karma,karma. $+ $nick),3,32),$ifmatch,0) вы поблагодарили: $iif($gettok($hget(karma,karma. $+ $nick),4,32),$ifmatch,0) $+ . В online: $duration($hget(karma,online. $+ $nick)) $+ , + $+ $calc($hget(karma,online. $+ $nick) / 86400) к вашей карме }
     }
}
on *:PART:*: {
   if $nick != $me { hadd karma online. $+ $nick $calc($ctime - $hget(karma,join. $+ $nick)) | hdel karma join. $+ $nick }
}
on *:NICK: {
   if $newnick != $me { hadd karma join. $+ $newnick $iif($hget(karma,join. $+ $nick),$ifmatch,$ctime) | hadd karma online. $+ $newnick $iif($hget(karma,online. $+ $nick),$ifmatch,0) | hdel karma join. $+ $nick | hdel karma online. $+ $nick }
}
on *:QUIT: {
   if $nick != $me { hadd karma online. $+ $nick $calc($ctime - $hget(karma,join. $+ $nick)) | hdel karma join. $+ $nick }
}

Сервис бот

[StingeR] — Mon, 20 Sep 2010 10:42:32 GMT

Форум: mIRC скриптинг
Описание темы: Самый наипростейший бот
Автор темы: [StingeR]
Автор последнего сообщения: [HeHaBu}I{y_DoM_2]
Количество ответов: 6

Написание диалоговых окон в mIRC

[StingeR] — Mon, 20 Sep 2010 10:37:29 GMT

Написание диалоговых окон в mIRC

С появлением новой версии mIRC, 5.5 появилась новая возможность - диалоговые окна, диалоги. Это было то, что требуется для написания скриптов более высокого уровня, для тех, кто до сих пор пытался использовать графические окна для создания более дружественного интерфейса с пользователем. Для нормального восприятия этой статьи неплохо было бы знать основы написания скриптов. Не рекомендуется для новичков в этом деле. Следующие разделы написания скриптов для mIRC неплохо было бы знать для нормального изучения этой статьи.

Использование переменныхидентификаторов (variablesidentifiers)
Знание алиасов (aliases)
Базовые знания скриптов (remote)

Для работы всего, что приведено в примерах требуется наличие mIRC 5.51, но не менее, т.к. со времён 5.5 были некоторые добавления, касающиеся диалогов. И вообще, хорошо писать скрипты используя последнюю версию mIRC, которая всегда доступна на http://www.mirc.com/get.html. Для тех, кто все ещё интересуется, что же это за такие диалоговые окна - продолжаете читать и вставлять примеры в редакторе mIRC. Вы получите ясную картину и понятие, что же это за такое. Ну хватит предыстории, приступим к скриптописательству. В этой статье я вас не буду учить писать диалоговые окна так как их можно с легкостью сделать при помощи программы дстудио, но в этой статье я вам покажу как заставить диалог функционировать(к примеру выполнять какую нибудь команду при нажатии на кнопочку). Ниже осмотрим События, некоторые команды и идентификаторы для работы с диалоговыми окнами.

Примечание ID пишется после элемента управления(к примеру: edit "",1,..... здесь ид=1, button "button",112,... здесь ид=112)

The On Dialog event

Если пользователь изменил значение элемента управления в окне (щелкнул кнопку, ввел текст) вызывается обработчик события.

on 1:dialog:name:event:id: {
echo $dname $devent $did
}

Где name – имя окна, id – идентификатор элемента управления, event может быть:

init перед открытием окна значения элементов управления могут быть проинициализированы. id =0.
close закрытие окна.
edit изменен тест в редакторе или состояние combo box.
sclick одиночный клик на list/combo box, поставлена или снята отметка на radio/check или нажата кнопка.
dclick двойной клик на list/combo box.
menu выбран элемент меню.
scroll позиция элемента scroll изменена.

Также вы можете определять mouse events:

mouse перемещение мыши
sclick левая кнопка нажата
uclick левая кнопка отжата
dclick двойной клик
rclick клик на правой кнопке
drop drop click

Идентификатор $mouse определяет текущую позицию окна.

Команда /did

Команда /did служит для изменения значений элементов управления окна (например, изменить текст в окне редактора, установить фокус на кнопку, удалить строчку из listbox).

/did -ftebvhnmcukradiogj name id [n] [text | filename]

-f установить фокус на элемент управления [id]
-t установить кнопку по умолчанию
-e разрешить элемент управления [id]
-b запретить элемент управления [id]
-v сделать видимым элемент управления [id]
-h спрятать элемент управления [id]
-n разрешить элемент editbox
-m запретить элемент editbox
-c отметить checkbox/radiobutton, строку list/combo
-u снять отметку checkbox/radiobutton, со строки list/combo
-k не изменять существующих отметок в listbox (работает вместе с –cu)
-r очистить текст в элементе управления [id]
-a добавить текст к концу строки
-d удалить N-ую строку
-i вставить N-ую строку
-o перезаписать N-ую строку
-g установить новую иконку/изображение в icon control
/did -g name id [n] filename -z сбросить ширину горизонтального scrollbar в элементе listbox
-j сбросить изменения в элементе editbox

Где name - это идентификатор диалогового окна, id - это номер элемента.
Если вы хотите изменить значения сразу нескольких элементов, укажите несколько номеров [id] разделенных запятой, например: /did -b name 2,12,14,16 и т.д.
Вы можете выбрать часть текста в элементе editbox, начиная с позиции N, используя команду /did -c name id [n] [start [end]].
Вы можете отметить 3state в элементе checkbox как неопределенную используя сразу два ключа -cu.
Чтобы получить доступ к редактированию элемента combobox используйте N = 0.
Чтобы изменить длину элемента scrollbar используйте команду /did -z name id [min max].

Идентификатор $did()

Вы можете получить значения и состояния элементов управления, используя идентификатор $did().

$did(name,id)
$did(name,id,N)

Если используется в обработчике события окна, name не указывается.

Свойства идентификаторы $did():

text возвращает строку или N-ую строку
$did(id) - то же самое, что и $did(id).text len возвращает длину строки или длину N-ой строки
lines возвращает количество строк
sel возвращает номер N-ой отмеченной линии
если N == 0, возвращает количество отмеченных линий seltext возвращает выделенный текст в элементе editbox или первый выделенный item в элементе listbox
selstart возвращает первый выделенный символ в строке элемента editbox
selend возвращает последний выделенный символ в строке элемента editbox
edited возвращает $true текст в элементе editbox был изменен
state возвращает 0 = выключено, 1 = включено, и 2 = не определено
next возвращает id следующего элемента управления (tab key order)
prev возвращает id предыдущего элемента управления (tab key order)
visible возвращает $true если элемент виден, в противном случае $false
enabled возвращает $true если элемент разрешен, в противном случае $false

Чтобы получить доступ к редактированию элемента combobox используйте N = 0.

Идентификатор $didwm(name,id,wildtext,N)

Возвращает номер строки которая содержит wildtext, начиная поиск со строки N. Параметр N не обязателен.

Идентификатор $didreg(name,id,regex,N)

Возвращает номер строки содержащей regex, начиная поиск со строки N. Параметр N не обязателен.

Идентификатор $didtok(name,id,C)

Возвращает список токенов в элементах list/combo/edit box.

Чтобы добавить список токенов в элементы list/combo/edit box, используйте команду /didtok name id C text.

Теперь давайте рассмотрим несколько примеров:

Code

alias enterpass dialog -m Enterpass Enterpass
dialog Enterpass {
title "Введите ваш пароль"
size -1 -1 300 60
edit "",1,20 10 260 20, pass
button "&OK",2,21 30 129 17, ok
button "&Cancel",3,150 30 130 17, cancel
}
on *:DIALOG:Enterpass:sclick:2: {
msg nickserv identify $did(1) }

В этом скрипте при нажатии /enterpass откроется диалоговое окно в котором надо ввести пароль и нажать ок, при нажатии ок скрипт посылает запрос идентификации NickServ'у.

Code

alias proverka dialog -m proverka proverka
dialog proverka {
title "Проверка"
size -1 -1 300 60
edit "",1,20 10 260 20
button "&OK",9,21 30 129 17, ok
button "&Cancel",3,150 30 130 17, cancel
}
on *:DIALOG:proverka:sclick:9: {
echo -a proverka proshla uspeshno vi vveli v okno vvoda: $+ $did(1) }

Этот скрипт анологичен прошлому результат увидите сами

Code

dialog test {
   title "test"
   size -1 -1 141 67
   option dbu
   list 1, 4 12 50 50, size
   button "add", 2, 81 24 37 12
   edit "", 3, 64 13 71 10
}
on *:DIALOG:test:sclick:2: {
did -a test 1 $did(3) }

наберите /dialog -m test test и наберите в правом окне ввода любое слово после чего нажмите add и этот текст появится в списке(слева)